I made a sample which a marker will be displayed if you put address of name of the specific place.

Cool reference:
Google Maps API for Flash ジオコーディング » interact!ve

　
Demo

You will see it if you click the following image.

　
Code

The code is below.

package
{
	import com.bit101.components.*;
	import com.google.maps.controls.MapTypeControl;
	import com.google.maps.controls.ZoomControl;
	import com.google.maps.InfoWindowOptions;
	import com.google.maps.LatLng;
	import com.google.maps.Map;
	import com.google.maps.MapEvent;
	import com.google.maps.MapMouseEvent;
	import com.google.maps.MapType;
	import com.google.maps.overlays.Marker;
	import com.google.maps.overlays.MarkerOptions;
	import com.google.maps.services.ClientGeocoder;
	import com.google.maps.services.GeocodingEvent;
	import flash.display.Sprite;
	import flash.events.Event;
	import flash.events.MouseEvent;
	import flash.geom.Point;

	/**
     *  document class
     */
    public class MapTest03 extends Sprite
    {
		private var map:Map = new Map();	// map
		private var geocoder:ClientGeocoder; //Geocoding
		private var geoSearchButton:PushButton;
		private var geoClearButton:PushButton;
		private var geoSearchText:InputText;	

		/**
         *  constructor
         */
        public function MapTest03()
        {
			map.addControl(new ZoomControl());	// zoom
			map.addControl(new MapTypeControl());	// map type
			map.key = "YOUR Google Maps API Key";

			map.setSize(new Point(stage.stageWidth, stage.stageHeight - 50));
			map.y = 50;
			map.addEventListener(MapEvent.MAP_READY, onMapReady);
			addChild(map);

			// searchText + Buttons
			geoSearchText = new InputText(this, 10, 15, "address or name");
			geoSearchButton = new PushButton(this, 380, 15, "Search!", geoSearch);
			geoClearButton = new PushButton(this, 490, 15,"Clear Marker", geoClear);
			geoSearchText.width = 360;
			geoSearchText.height = geoSearchButton.height;

			addChild(geoSearchText);
			addChild(geoSearchButton);
			addChild(geoClearButton);
        }

		/**
		* geoSearch
		*
		* @access private
		* @param e:MouseEvent
		* @return void
		*/
		private function geoSearch(e:MouseEvent):void{
			var geoSearch:String = geoSearchText.text;
			if(geoSearch){
				geocoder.geocode(geoSearch); // geocodes for user-specified addresses
			}
		}

		/**
		* geoClear
		*
		* @access private
		* @param e:MouseEvent
		* @return void
		*/
		private function geoClear(e:MouseEvent):void{
			map.clearOverlays();
		}

		/**
		* handleGeocodingSuccess // Geocoding succeeded event
		*
		* @access private
		* @param e:GeocodingEvent
		* @return void
		*/
		private function handleGeocodingSuccess(e:GeocodingEvent):void{
			var placemarks:Array = e.response.placemarks; // Object containing the result returned by the geocoder in case the request completes successfully or null in case of failure.
			if(placemarks.length > 0){
				map.setCenter(placemarks[0].point); // setting LatLng
				trace(placemarks[0].address); // // address
				//trace(placemarks[0].addressDetails); // address object

				var marker:Marker = new Marker(placemarks[0].point);
				marker.addEventListener(MapMouseEvent.CLICK, function(event:Event):void {
				marker.openInfoWindow(new InfoWindowOptions(
												  {title:placemarks[0].address,content:placemarks[0].point.toString()}));
				});
				map.addOverlay(marker); // add marker
			}
		}

		/**
		* handleGeocodingFailure // Geocoding failure event
		*
		* @access private
		* @param e:GeocodingEvent
		* @return void
		*/
		private function handleGeocodingFailure(e:GeocodingEvent):void{
		}

		/**
		* onMapReady
		*
		* @access private
		* @param e:Event
		* @return void
		*/
		private function onMapReady(event:Event):void {
			map.setCenter(new LatLng(49.279705, -123.115625), 16, MapType.NORMAL_MAP_TYPE);
			geocoder = new ClientGeocoder();
			//register Geocoding succeeded event
			geocoder.addEventListener(GeocodingEvent.GEOCODING_SUCCESS, handleGeocodingSuccess);
			// register Geocoding failure event
			geocoder.addEventListener(GeocodingEvent.GEOCODING_FAILURE, handleGeocodingFailure);
		}
    }
}

Cool reference:
Google Maps API for Flash 緯度・経度の表示 » interact!ve

　
Demo

You will see it if you click the following image.

　
Code

The code is below.

package
{
	import com.google.maps.controls.MapTypeControl;
	import com.google.maps.controls.ZoomControl;
	import com.google.maps.InfoWindowOptions;
	import com.google.maps.LatLng;
	import com.google.maps.Map;
	import com.google.maps.MapEvent;
	import com.google.maps.MapMouseEvent;
	import com.google.maps.MapType;
	import com.google.maps.overlays.Marker;
	import com.google.maps.overlays.MarkerOptions;
	import flash.display.Sprite;
	import flash.events.Event;
	import flash.geom.Point;

	/**
     *  document class
     */
    public class MapTest02 extends Sprite
    {
		private var map:Map = new Map();	// map
		private var marker:Marker;	// marker

		/**
         *  constructor
         */
        public function MapTest02()
        {
			map.addControl(new ZoomControl());	// zoom
			map.addControl(new MapTypeControl());	// map type
			map.key = "YOUR Google Maps API Key";

			map.setSize(new Point(stage.stageWidth, stage.stageHeight));
			map.addEventListener(MapEvent.MAP_READY, onMapReady);
			map.addEventListener(MapMouseEvent.CLICK, onMapClick); // add EventListener
			addChild(map);

        }

		/**
		* onMapReady
		*
		* @access private
		* @param e:Event
		* @return void
		*/
		private function onMapReady(e:Event):void {
			map.setCenter(new LatLng(49.279705, -123.115625), 16, MapType.NORMAL_MAP_TYPE);
		}

		/**
		* onMapClick
		*
		* @access private
		* @param e:MapMouseEvent
		* @return void
		*/
		private function onMapClick(e:MapMouseEvent):void {
			var latLng:String = e.latLng.toString(); // convert a coordinate data to a string
			map.openInfoWindow(e.latLng,
				new InfoWindowOptions({title: "clicked the map!", content: latLng}));
		}

    }
}

If you want to use Google Maps in Flash, you should use Google Maps API for Flash. Though Flash CS3 was used in the official tutorial, I guess the point you should care is just the change of position of the swc file.

Cool reference:
Integrate Google Maps into Flash CS4 | Flash tutorials | CS5 | Actionscript | flash animation | HowTo
Google Maps API for Flash » interact!ve

　
Before using Google Maps API for Flash

1. Get a Google Maps API Key at Sign up for a Google Maps API Key

2. Download the Software Development Kit (SDK) at Download the Google Maps API for Flash SDK

3. If you unzip the SDK you have downloaded, in the sdk/lib folder of the SDK you’ll find a file named “map_1_20.swc” and “map_flex_1_20.swc”. (Feb 8, 2011)

4. To install this API, If you’re on a Mac / Flash CS5, create a folder named “Google” in [user folder]/Library/Application Support/Adobe/Flash CS5/language/Configuration/Components and put “map_1_20.swc” into this new directory.

5. Restart Flash if you had it open before trying to work with the API.

6. Open the Components panel by selecting it from the Window menu. You will find a folder named “Google”. Twirl down the folder and you will see the GoogleMapsLibrary component. Drag the component into the stage to add it to your project. Now, you’ll be able to access all of the Google Maps APIs.

　
Demo

I made a easy sample. You will see it if you click the following image.

　
Code

The code is below.

package
{
	import com.google.maps.controls.MapTypeControl;
	import com.google.maps.controls.ZoomControl;
	import com.google.maps.InfoWindowOptions;
	import com.google.maps.LatLng;
	import com.google.maps.Map;
	import com.google.maps.MapEvent;
	import com.google.maps.MapMouseEvent;
	import com.google.maps.MapType;
	import com.google.maps.overlays.Marker;
	import com.google.maps.overlays.MarkerOptions;
	import flash.display.Sprite;
	import flash.events.Event;
	import flash.geom.Point;

	/**
     *  document class
     */
    public class MapTest01 extends Sprite
    {
		private var map:Map = new Map();	// map
		private var marker:Marker;	// marker

		/**
         *  constructor
         */
        public function MapTest01()
        {
			map.addControl(new ZoomControl());	// zoom
			map.addControl(new MapTypeControl());	// map type
			map.key = "YOUR Google Maps API Key";
			map.setSize(new Point(stage.stageWidth, stage.stageHeight));
			map.addEventListener(MapEvent.MAP_READY, onMapReady);
			addChild(map);

        }

		/**
		* onMapReady
		*
		* @access private
		* @param e:Event
		* @return void
		*/
		private function onMapReady(e:Event):void {
			map.setCenter(new LatLng(49.279705, -123.115625), 16, MapType.NORMAL_MAP_TYPE);
			// marker
			marker = new Marker(map.getCenter(), new MarkerOptions())
			marker.addEventListener(MapMouseEvent.CLICK, onClick);
			map.addOverlay(marker);
		}

		/**
		* onClick
		*
		* @access private
		* @param e:Event
		* @return void
		*/
		private function onClick(e:Event):void {
			marker.openInfoWindow(new InfoWindowOptions( { content:"VPL Central Library" } ));
		}

    }
}

　
To use Google Maps API for Flash on website

You have to set Local playback security to Access network only.
[FlashCS5] File -> Publish Settings -> Flash -> Local playback security.

Furthermore, You have to put your API key into flashvars.
In the case of swfObject2.2, the code is below.

<script type="text/javascript">
var flashvars = {
	'key':'your_api_key','sensor': true_or_false
}
var params = {};
var attributes = {};
swfobject.embedSWF("MapTest01.swf", "content", "600", "400", "9.0.0","", flashvars, params, attributes);
</script>

var obj:Object = XMLUtil.xmlToObject( XMLList(dataHolder.data) );

これで問題ないはずがエラーが出る。Progression フォーラムによると,

Flash CS5 では、標準ライブラリの中に XMLUtil クラスが増えているようです。
そのために、内部で使用している XMLUtil クラスが jp.nium.utils.XMLUtil を指すはずが、パッケージパスのない XMLUtil クラスを向いてしまい、コンパイルエラーとなってしまっているようです。

XMLUtil.xmlToObject() -> jp.nium.utils.XMLUtil.xmlToObject()

とのこと。以下のように記述すれば好い。

var obj:Object = jp.nium.utils.XMLUtil.xmlToObject( XMLList(dataHolder.data) );

JAM 用に作りました。もちろん鼻毛を抜きながらね。
鼻毛処理のお供にどうぞ。

鼻毛を抜いて並べていきます。0秒になると鼻血ブー（by 谷岡ヤスジ）します。
当初は鼻息で鼻毛を飛ばそうと想ってました。鼻毛用ハサミは単なる飾りです。

音をつけたりグラフィックや位置、動きを調整するともっと好い感じになるはず。
7/30 締切らしいのでとりあえずこのまま。

キャプチャが fork 元のから変わらないんだけど何故？

var tf:TextField = new TextField();
tf.text = "お願い！マスクして！お願い！マスクして！お願い！マスクして！お願い！マスクして！お願い！マスクして！お願い！マスクして！お願い！マスクして！お願い！マスクして！"
tf.selectable = true;
tf.wordWrap = true;
tf.width = 150;
addChild(tf);

var ball:Sprite = new Sprite();
ball.graphics.beginFill(0xFF0000);
ball.graphics.drawCircle(0, 0, 50);
addChild(ball);
tf.mask = ball;

とすれば好いはずですが、何度お願いしてもこの場合円の矩形の範囲でマスクされてしまいます。
その形でマスクするには 両方のcacheAsBitmap を trueにします。

tf.cacheAsBitmap = true;
ball.cacheAsBitmap = true;

参考

• にゃあプロジェクト – ウェブログ – テキストフィールドにマスク
• feb19.jp blog – ランタイムビットマップキャッシュ（.cacheAsBitmap）
• cacheAsBitmapの法則 – なんたらノート 第二期

レベルがあまりに高すぎてビビりつつずっとサボってたwonderflをまたやり始めました。
パーティクル祭に乗り遅れること半年以上、今日からちまちま1人パーティクル祭りやってくよー。
第1回目の今日はとりあえず放射線状に発射。

配列から重複せずにn個取り出して新しい配列を返すRandomExtractクラス

package
{
	public class RandomExtract
	{
		/**
		 * コンストラクタ
		 *
		 * @access public
		 * @param
		 * @return void
		 */
		public function RandomExtract():void
		{
		}

		/**
		 * ランダムに配列の値を取り出す
		 *
		 * @access public
		 * @param array 元になる配列
		 * @param num 取り出す配列の個数
		 * @return Array
		 */
		public static function random(array, num):Array
		{
			var a:Array = array;
			var t:Object = {};
			var r:Array = [];
			var l:int = a.length;
			var n:int = num < l ? num : l;
			while (n-- > 0) {
				//配列の数からランダムな値を作成
				var i = Math.random() * l | 0;
				r[n] = t[i] || a[i];
				//  t[i]がundefinedにならない処理
				--l;
				t[i] = t[l] || a[l];
			}
			return r;
		}
	}
}

例えば10個の配列から3個の値を取り出したい時は以下のように記述します。

import RandomExtract;

var arr:Array = [0, 1, 2, 3, 4, 5, 6, 7, 8, 9];
var num:int = 3;

var newArr:Array = RandomExtract.random(_arr, _num);
trace(newArr + "が取り出されるんだぜ");

出力結果はこんな感じです。

2,1,6が取り出されるんだぜ

参考サイトがあってそこのコードを自分に分かりやすいように書き換えただけなのですが、どこだったか分からなくなってしまいました。見つけたら追記します。

[9/21 追記]
ムダにRandomExtractクラスをインスタンス化していたのでrandomメソッドをstaticに修正。

以下のようにして受け取ります。

var flashVars:Object = loaderInfo.parameters;
for (var i:String in flashVars) {
	_txt.appendText(i + "=" + flashVars[i] + "\n");
}

受け取りたいFlashVarsの値の中身が複数あって、それぞれ別々の場所に格納したい以下のような場合には、

nickname=ore&age=10014

for…inループの変数部分にはObjectのプロパティ名が入ります。文字列を追加したいTextfieldを各プロパティ名に対応する値として格納しておくことで、別々のTextfieldに追加することができます。

var flashVars:Object = loaderInfo.parameters;
var txtData:Object = {nickname:name_txt, age:age_txt};
for (var i:String in flashVars) {
	txtData[i].appendText(flashVars[i]);
}

上記ページを参考に俺もやってみました。Index.asの_onInitに以下の記述を追加して、

//コンテキストメニューを非表示
Progression.uiContextMenu.enabled = false;
CastObjectContextMenu.enabled = false;
CastButtonContextMenu.enabled = false;

このままだとエラーが出たのでimport文を追加。

import jp.progression.core.ui.CastButtonContextMenu;
import jp.progression.core.ui.CastObjectContextMenu;

これで右クリックすると「Powered by Progression 3.1.62」「設定」「Adobe Flash Player 10 について」の表示になりました。フォーラムではimport文を書いてもダメだったとあったけど…何ででしょ。
「印刷する」だけとか個別に設定したい時は以下を参考に設定。

CastObjectContextMenu – Progression 3.1 – API Reference
CastButtonContextMenu – Progression 3.1 – API Reference